[Querydsl] Unable to load class 'com.mysema.codegen.model.Type' 에러 해결 방법

스프링 부트 2.7 버전 이상과 Querydsl 5.0 버전 이상을 설정할 때 발생하는 에러입니다.

 

 

Q타입 클래스를 만들기 위해 Gradle -> Tasks -> Other -> compileQuerydsl을 실행할 때 발생합니다.

 

Querydsl과 gradle 설정 정보가 일치하지 않기 때문입니다.

 

1. 그러므로 build.gradle에 querydsl 버전 설정을 추가한 후

buildscript {
    ext {
        queryDslVersion = "5.0.0"
    }
}

 

2. dependencies에 아래 2줄을 추가하면 됩니다.

implementation "com.querydsl:querydsl-jpa:${queryDslVersion}"
annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}"

 

즉 querydsl의 버전을 명시하고, querydsl-jpa, querydsl-apt를 추가하면 해결할 수 있습니다.

 

 

정상적으로 compileQuerydsl이 실행됩니다.

compileQuerydsl 정상 실행

Q타입 클래스가 정상적으로 생성된 것을 볼 수 있습니다.

 

 

 

전체 build.gradle 코드 입니다.

buildscript {
    ext {
        queryDslVersion = "5.0.0"
    }
}

plugins {
    id 'java'
    id 'org.springframework.boot' version '2.7.7'
    id 'io.spring.dependency-management' version '1.0.15.RELEASE'
    id 'com.ewerk.gradle.plugins.querydsl' version '1.0.10'
}

group = 'study'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'

    implementation "com.querydsl:querydsl-jpa:${queryDslVersion}"
    annotationProcessor "com.querydsl:querydsl-apt:${queryDslVersion}"

    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.8.1'

    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
    useJUnitPlatform()
}

//querydsl 추가 시작
def querydslDir = "$buildDir/generated/querydsl"

querydsl {
    jpa = true
    querydslSourcesDir = querydslDir
}

sourceSets {
    main.java.srcDir querydslDir
}

configurations {
    querydsl.extendsFrom compileClasspath
}

compileQuerydsl {
    options.annotationProcessorPath = configurations.querydsl
}
//querydsl 추가 끝